initial commit

PKGBUILD

@@ -0,0 +1,45 @@
+# Maintainer: Colin Reeder <colin AT reederhome DOT net>
+pkgname=pa-applet-git
+pkgver=19.3b4f8b3
+pkgrel=1
+pkgdesc="PulseAudio control applet"
+arch=(i686 x86_64)
+url="https://github.com/fernandotcl/pa-applet"
+license=('BSD')
+depends=('gtk3' 'libnotify' 'libpulse')
+makedepends=('git')
+options=('!libtool')
+
+source=(
+    "$pkgname"::'git://github.com/fernandotcl/pa-applet.git'
+    'smaller_volume_step.patch'
+)
+
+sha256sums=(
+    'SKIP'
+    '889a9d5fadd29032655cef126b6c3895121706865098c249636be5b3d9d3fbd2'
+)
+
+pkgver() {
+    cd "$pkgname"
+    echo $(git rev-list --count HEAD).$(git rev-parse --short HEAD)
+}
+
+prepare() {
+    cd "$pkgname"
+    patch --forward --strip=1 --input="${srcdir}/smaller_volume_step.patch"
+}
+
+build() {
+    cd "$srcdir/$pkgname"
+    CFLAGS+=" -Wno-error"
+    ./autogen.sh
+    ./configure --prefix=/usr
+    make -j$(nproc)
+}
+
+package() {
+    cd "$srcdir/$pkgname"
+    make DESTDIR="$pkgdir/" install
+    install -D -m644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+}

smaller_volume_step.patch

@@ -0,0 +1,13 @@
+diff --git a/src/audio_status.c b/src/audio_status.c
+index ab0d125..41f8aab 100644
+--- a/src/audio_status.c
++++ b/src/audio_status.c
+@@ -7,7 +7,7 @@
+  *
+  */
+ 
+-#define STATUS_STEP_SIZE 5.0
++#define STATUS_STEP_SIZE 2.0
+ 
+ #include "audio_status.h"
+