pa-applet-git/PKGBUILD

# Maintainer: Colin Reeder <colin AT reederhome DOT net>
pkgname=pa-applet-git
pkgver=19.3b4f8b3
pkgrel=3
pkgdesc="PulseAudio control applet"
arch=(i686 x86_64)
url="https://github.com/fernandotcl/pa-applet"
license=('BSD')
depends=('gtk3' 'libnotify' 'libpulse')
makedepends=('git')
options=('!libtool')

source=(
    "$pkgname"::'git+https://github.com/fernandotcl/pa-applet.git'
    'smaller_volume_step.patch'
)

b2sums=(
    SKIP
    904312b9170b3a7c8e5c1f3fece067e41db987866b208d98594e408a527de00e3b0e500a8557655ef14582492f37eff380ad01e53cf64b67f8cdd20ad2c34646
)

pkgver() {
    cd "$pkgname"
    echo $(git rev-list --count HEAD).$(git rev-parse --short HEAD)
}

prepare() {
    cd "$pkgname"
    patch --forward --strip=1 --input="${srcdir}/smaller_volume_step.patch"
}

build() {
    cd "$srcdir/$pkgname"
    CFLAGS+=" -Wno-error"
    ./autogen.sh
    ./configure --prefix=/usr
    make
}

package() {
    cd "$srcdir/$pkgname"
    make DESTDIR="$pkgdir/" install
    install -D -m644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}