indicator-kdeconnect-git/PKGBUILD

# Maintainer: Sebastian Gumprich <aur at gumpri dot ch>
# Contributor: shimi <shimi.chen@gmail.com>
# Contributor: Gustavo Castro <gustawho at gmail dot com>
pkgname=indicator-kdeconnect-git
pkgver=r625.669bdd5
pkgrel=1
_gitname=indicator-kdeconnect
pkgdesc="Integrate KDEConnect on desktop environments that use AppIndicators (e.g. Unity)"
arch=('x86_64')
url="https://github.com/b4j4/indicator-kdeconnect"
license=('GPL')
conflicts=('indicator-kdeconnect')
provides=('indicator-kdeconnect')
depends=('libappindicator-gtk3' 'kdeconnect' 'vala' 'python-requests-oauthlib' 'python-gobject' 'libgee')
makedepends=('git' 'meson' 'ninja')
source=(
  'git+https://github.com/bajoja/indicator-kdeconnect.git'
  'fix-build.patch'
)
sha256sums=(
  'SKIP'
  'b79c5b3b3cda6b7e9e329ae1ea080f8750dde64025090b9cb534efb7a2c0f537'
)

pkgver() {
  cd $_gitname
  printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}

prepare() {
    cd "$_gitname"
    patch --forward --strip=1 --input="${srcdir}/fix-build.patch"
}

build() {
  mkdir build && cd build
  meson ../$_gitname --prefix=/usr  --libdir=/usr/lib
  ninja
}

package() {
  cd build
  DESTDIR=$pkgdir ninja install
}